Overloads Public Sub Add(DataRelation)
Overloads Overridable Public Function Add(DataColumn, DataColumn) As DataRelation
Overloads Overridable Public Function Add(DataColumn(), DataColumn()) As DataRelation
Overloads Overridable Public Function Add(String, DataColumn, DataColumn) As DataRelation
Overloads Overridable Public Function Add(String, DataColumn(), DataColumn()) As DataRelation
Overloads Overridable Public Function Add(String, DataColumn, DataColumn, Boolean) As DataRelation
Overloads Overridable Public Function Add(String, DataColumn(), DataColumn(), Boolean) As DataRelation

例題を上記各レコードのカテゴリIDとSQL Serverのカテゴリマスタテーブルとのリレーションを作成し、各製品をカテゴリ別に分類するようなものにしようと思います。

まずは今までのおさらいで、各データを DataSet の Tables コレクションに取り込んでいきます。
ちなみにここでは データの取り込みに関するコードは省略させていただき、後でまとめて記述しようと思います。
私はそれぞれ CATEGORY と SOFT という キー で DataTable を作成しました。

次はいよいよリレーションの作成です。
例題では各テーブルどうしのリレーションを指定する列は1つであり、データ出力の際にアクセスするためのキーが必要であることから、4番目か6番目のAddメソッドが妥当ですね。
このAddメソッドに関してもう少し、きちんとした定義内容を挙げておきます。

Overridable Overloads Public Function Add( _
   ByVal name As String, _
   ByVal parentColumn As DataColumn, _
   ByVal childColumn As DataColumn _
) As DataRelation

Overridable Overloads Public Function Add( _
   ByVal name As String, _
   ByVal parentColumn As DataColumn, _
   ByVal childColumn As DataColumn _
   ByVal createConstraints As Boolean _
) As DataRelation

oDS.Relations.Add("SOFTLIST", oDS.Tables("CATEGORY").Columns("CatID"), oDS.Tables("SOFT").Columns("CatID"))

    TreeView1.Nodes.Add , , "Parent", "親ノード"
    TreeView1.Nodes.Add "Parent", tvwChild, "Child", "子ノード"

    TreeView1.Nodes.Add("親ノード").Nodes.Add("子ノード")

    Dim nodParent As TreeNode
    nodParent = TreeView1.Nodes.Add("親ノード")
    nodParent.Nodes.Add("子ノード")
        

    Dim rowCate As DataRow
    Dim rowSoft As DataRow
    Dim nodCate As TreeNode

    Button1.Enabled = False

    '-- 列データをTreeViewに出力する。
    For Each rowCate In oDS.Tables("CATEGORY").Rows
        nodCate = TreeView1.Nodes.Add(rowCate("Category").ToString)
        For Each rowSoft In rowCate.GetChildRows("SOFTLIST")
            nodCate.Nodes.Add(rowSoft("NAME").ToString)
        Next
    Next

　

今回完成したコード

Option Strict On
'-- System.Data.SqlClientネームスペース
Imports System.Data.SqlClient
Imports System.Data.OleDb

Public Class Form1
    Inherits System.Windows.Forms.Form

    Private oDS As DataSet
    Private adpSoft As OleDbDataAdapter
    Private adpCate As SqlDataAdapter

    Private Sub Button1_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button1.Click

        Dim rowCate As DataRow
        Dim rowSoft As DataRow
        Dim nodCate As TreeNode

        Button1.Enabled = False

        '-- 列データをTreeViewに出力する。
        For Each rowCate In oDS.Tables("CATEGORY").Rows
            nodCate = TreeView1.Nodes.Add(rowCate("Category").ToString)
            For Each rowSoft In rowCate.GetChildRows("SOFTLIST")
                nodCate.Nodes.Add(rowSoft("NAME").ToString)
            Next
        Next

    End Sub

    Private Sub Form1_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load

        oDS = New DataSet("DATASET1")

        adpCate = New SqlDataAdapter("SELECT * FROM T_CATEGORY", _
                                  "Data Source=○○○○;Initial Catalog=TestDB;UID=○○;PWD=○○")
        adpCate.Fill(oDS, "CATEGORY")

        adpSoft = New OleDbDataAdapter("SELECT * FROM T_SOFT", _
                                          "Provider=Microsoft.Jet.OLEDB.4.0;Data Source=Test.mdb")
        adpSoft.Fill(oDS, "SOFT")


        '-- 各データセットでリレーションを作成
        oDS.Relations.Add("SOFTLIST", oDS.Tables("CATEGORY").Columns("CatID"), oDS.Tables("SOFT").Columns("CatID"))

    End Sub

    Private Sub Form1_Closing(ByVal sender As Object, ByVal e As System.ComponentModel.CancelEventArgs) Handles MyBase.Closing
        '-- 各オブジェクトの開放
        oDS.Clear()
        oDS.Dispose()
        oDS = Nothing
        adpSoft.Dispose()
        adpSoft = Nothing
        adpCate.Dispose()
        adpCate = Nothing
    End Sub

End Class

今回もADO.NETについてふれましたが、その中でちょこっと使った TreeView コントロールを見て 「他のコントロールはどう変わったの」と気になって仕方ありません。
次回からは Windows.Forms の各コントロールについて VB6での使い方と比較しながら、違いを洗い出してみようと思います。
ADO.NETについてはまだほんの僅かしか試していませんが、また必要な機会に追々触れていこうと思います。